加藤さん
おいそがしいところありがとうございました
どちらも無事動作しました
しばらくいろいろと試してみたいと思います

引用：

ついでですので、キーカラーの数を指定できるように入力ダイアログを追加してみました。

キーカラーの数は一応 24 までに制限してありますが、書き換えればいくつでも増やせます。

これを Sghade 8, 9 で動かす場合は、

42行目

set n_Child to (number of sons of active shape 1 of scene 1)

を次のように書き換えて下さい

set n_Child to (number of sons of shape 1 of active objects of scene 1)


-----　　ここからハサミでチョッキン　　-----

tell application "Shade 10"

-- 入力ダイアログ - 1
activate

begin dialog 10 -- dialog ID には適当な数字を入れてください

append int dialog item "指定する色の数（２〜 24 ）"
if ask dialog then
set n_color to (get int property value 0) -- 色を指定するダイアログの数を与えます。
end dialog
if n_color < 2 or n_color > 24 then
beep
return
end if
else
return
end if


-- 入力ダイアログ - 2
begin dialog 20 -- dialog ID には適当な数字を入れてください

repeat with i from 1 to n_color -- RGB ダイアログを n_color 個作成
append RGB dialog item (i as text)
end repeat

set colorL to {} -- 入力ダイアログで指定される色を格納するリストを空リストとして作成
if ask dialog then
repeat with i from 1 to n_color
set colorL to colorL & {(get RGB property value (i - 1))} -- colorL にユーザーが指定する色を順次格納
end repeat
end dialog
else
return
end if


-- 処理
inhibit update
if object type = part object then -- 選択オブジェクトがパート（自由曲面やジョイント類を含む）なら
set n_Child to (number of sons of active shape 1 of scene 1) -- 選択されているオブジェクトの子の数を調べる
if n_Child > 1 then -- 子オブジェクトが2個以上存在する （n_child = 1 だと SetColor() の中でエラーとなってしまう）
select child
set counter to 1 -- 何番目の子であるかを示すカウンター
set base color to my SetColor(n_color, colorL, n_Child, counter) -- SetColor() で決定される拡散反射色をセットする
repeat (n_Child - 1) times
select brother
set counter to (counter + 1) -- カウンターを一つ進ませる
set base color to my SetColor(n_color, colorL, n_Child, counter)
end repeat
select parent
end if
end if
allow update
end tell


on SetColor(n_color, colorL, n_Child, counter) -- 色を設定する　sub-routine
-- n_color : 指定された色の数
-- colorL : 指定された色を格納したリスト
-- n_child : 子オブジェクトの総数
-- counter : 現在の子の番号（1から始まる）

set d to (n_color - 1) / (n_Child - 1)
set pos to d * (counter - 1) -- 4つの色が指定された場合、子オブジェクトの番号に応じて 0〜3( = 4 - 1) の数字を pos として割り当てる
set item_1 to (pos div 1) + 1 -- (pos div 1) で切り捨てとなる、例えば、pos = 0.5 ならば切り捨てられて　0、それに1を加えて結果 item_1 = 1 となる
if item_1 ≠ n_color then -- 選択されている子オブジェクトへの色を指定された色の間で定義するが、その際に使用される左側の色番号
set item_2 to (item_1 + 1) -- 選択されている子オブジェクトへの色を指定された色の間で定義するが、その際に使用される右側の色番号
else
set item_2 to item_1
end if

set pos to (pos - (pos div 1)) -- pos から自身を切り捨てた数値を引く、すなわち pos の小数点以下をあらためて pos として再定義
set color_1 to (item item_1 of colorL) -- 左側の色番号に従って colorL の中から左側の色を取り出す
set color_2 to (item item_2 of colorL) -- 右側の色番号に従って colorL の中から右側の色を取り出す

set red to ((item 1 of color_1) + pos * ((item 1 of color_2) - (item 1 of color_1))) -- color_1, color_2 の間で pos を使って中間の色の赤成分を決定
set green to ((item 2 of color_1) + pos * ((item 2 of color_2) - (item 2 of color_1))) -- 同上の緑成分
set blue to ((item 3 of color_1) + pos * ((item 3 of color_2) - (item 3 of color_1))) -- 同乗の青成分

set red to (red * 1000000 div 1) / 1000000 -- 本来は不必要だが試しに入れてみた
set green to (green * 1000000 div 1) / 1000000 -- 本来は不必要だが試しに入れてみた
set blue to (blue * 1000000 div 1) / 1000000 -- 本来は不必要だが試しに入れてみた

return {red, green, blue} -- RGB color としてリスト形式で返す
end SetColor

引用：

確認してみましたが、うまくいかないように見えるのは、上記の script ではオブジェクトの中心回りに回転させるのではなくて、座標原点回りに回転させてしまっているからだと思います。


ということで、オブジェクト中心に回転させるように書き加えました。


----　　ここからハサミでチョッキン　　-----

tell application "Shade 10"
-- 入力ダイアログ
activate --Shade を前面にもってくる
begin dialog 200 -- ダイアログの開始（dialog ID = 200 この番号は script 毎にユニークな値を割り当てる）
append vec3 dialog item "初期移動量" --0
append selection dialog item "移動量の変化/等差/等比" --1
append vec3 dialog item "移動量の変化（等比の場合は等比係数）" --2
append vec3 dialog item "初期回転量" --3
append selection dialog item "回転量の変化/等差/等比" --4
append vec3 dialog item "回転量の変化（等比の場合は等比係数）" --5
append selection dialog item "移動回転の順序/移動→回転/回転→移動" --6

if ask dialog then -- 入力ダイアログを開き、ユーザーがキャンセルしなかった
set trans to (get vec3 property value 0)
set transSel to (get selection property value 1)
set d_trans to (get vec3 property value 2)
set theta to (get vec3 property value 3)
set rotSel to (get selection property value 4)
set d_theta to (get vec3 property value 5)
set t_r to (get selection property value 6)
end dialog --ダイアログ終了
else
return -- ユーザーキャンセル
end if

inhibit update
if select child then
if t_r = 0 then -- 移動→回転
move object translate trans
move object rotate theta around center
else -- 回転→移動
move object rotate theta
move object translate trans around center
end if

repeat
if select brother then
if transSel = 0 then -- 等差
set trans to {(item 1 of trans) + (item 1 of d_trans), (item 2 of trans) + (item 2 of d_trans), (item 3 of trans) + (item 3 of d_trans)}
else -- 等比
set trans to {(item 1 of trans) * (item 1 of d_trans), (item 2 of trans) * (item 2 of d_trans), (item 3 of trans) * (item 3 of d_trans)}
end if

if rotSel = 0 then -- 等差
set theta to {(item 1 of theta) + (item 1 of d_theta), (item 2 of theta) + (item 2 of d_theta), (item 3 of theta) + (item 3 of d_theta)}
else -- 等比
set theta to {(item 1 of theta) * (item 1 of d_theta), (item 2 of theta) * (item 2 of d_theta), (item 3 of theta) * (item 3 of d_theta)}
end if

if t_r = 0 then -- 移動→回転
move object translate trans
move object rotate theta around center
else -- 回転→移動
move object rotate theta
move object translate trans around center
end if
else
exit repeat
end if
end repeat
select parent
end if
allow update
end tell

引用：


下のレスにも書いてありますが、


26行目

set n_Child to (number of sons of shape 1 of active objects of scene 1)

を次のように書き換えて下さい

set n_Child to (number of sons of active shape 1 of scene 1)


これで動くはずです

え〜っと、まずは Shade 10.0.2 での AppleScript に関する報告から、

10.0, 10.0.1 における諸々のバグは解消されています。

私が気づいた範囲内での報告になりますが、Shade 9 に対して変更となったのは、


１）ここのスレッドの 3/9 付けの書き込みにも書いてあるとうり、

クラス shape が変更された

例えば、選択されたオブジェクトの子オブジェクトの数を返す number of sons の場合、

Shade 9 では：

tell application "Shade 9"
number of sons of shape 1 of active objects of scene 1
end tell


Shade 10 では：

tell application "Shade 10"
number of sons of active shape 1 of scene 1
end tell


２）回転体を作成する solid revolve の書き方が変更された

Shade 9 では：
solid revolve from {0,0,0} to {100,0,0}

Shade 10 では：
solid revolve around {0,0,0} and {100, 0, 0}

はいな、お声がかかったようで、

すみません、今手が離せないので、今日の深夜に返信をば、

10.0.2アップデーターで
「文字掃引スクリプト1.2.3」、使えるようになってました。
それと、
http://lounge.shade-online.jp/modules/newbb/viewtopic.php?topic_id=914&forum=1
で
加藤さんから教えていただいたものも一部使えるようになってました。
「パートの中のオブジェクトにレインボウを設定」のスクリプトと
「パートの中全部のオブジェクトに-移動・回転を数値設定」
はまだダメなようです。（等差・回転は出来るようですが、等比部分がどうもうまくいかないようなんです）
加藤さん、ご覧になってましたら・・・

加藤さん
ありがとうございます
Shadeの仕様変更じゃなくバグだったんですか
次期、アップデータを待ってみます。

引用：

こんにちわ、
現在の Shade 10.0.1 では、Applescript のコアとなる部分に「 仕様変更 」ではない「 バグ 」と思われるものがかなり散見されますので、そのせいですね。

ですから、次期バージョンでバグフィックスされれば再び使用可能になることも十分期待できるのではないかと思います。

期待できなきゃいけないのですけどね。

バージョンアップされると、どうしても初期の段階ではなにがしかの script bug が見つかってしまうのは、これはもう仕方がないとして受け入れるしかないと思います。

まあ、今回はいつもに比べてると重傷ではありますが。

こんにちは
加藤さんから教えていただいたスクリプトが壊滅状態になってしまいました
これは、ある意味しかたがないとはおもいますが


私などは記録して使うことしかできませんので本体機能がプラグインになってしまったものなどは記録されず困ることもしばしばです

発売元には
せめて、以前からのShadeに付属されていたAppleScriptはPythonScriptに移植してほしいと思います
以外と、単機能の簡単なスクリプトが必要なことがあります
特に、「文字掃引スクリプト1.2.3」はぜひともほしいです

Shade9までは使えたのですが・・・。

雪見月さん、こんにちわ、

引用：

そうですね。
legacy も サポートするというのが原則だとは思うのですが。

ただ、スクリプトに限らず、ことプログラムものにおいては技術革新が早いので、過去の遺産に捕らわれずに、ドラスティックに変更というのもまた、常に求められることであるようです。

Windows Shade では VB script や tcl script もなくなって python 一本になってしまいましたが、現在の python だって10年後にそのまま使用できるかどうかは全くわかりませんしね。

プログラムものに手を染めてそれに馴染んでしまった場合、「書き直し」や「移植」という恐怖が常につきまとってくるように感じてしまい、ジレンマに陥ってしまうこともあります。


引用：

なんかパスの書き換えに便利なものがあったはずとおもってましたが、POSIX を使えばいいのですね、ありがとうございます。

引用：

自分のスクリプトの書き直しに参考にさせて頂きましたありがとうございます
スクリプトエディッタで『記録』で記録されるのは旧バージョンの書式なので
どこが悪いのか探すのに苦労しました

tell scene 1　とか
begin dialog にもbegin dialog 1　と言った具合に足さなければいけないし
以前のスクリプト資産を使うにはつらい状況ですね

ファイルパスの問題は
(POSIX path of file (:区切りのファイルパス))　→(/区切りのファイルパス)
((/区切りのファイルパス) as POSIX file )　→(:区切りのファイルパス)
で相互に変換できますが
フォトショップ等ほかのソフトに処理がまたがるものでは特に困りますね

Apple script のバグ報告の続き

引用：


同様の症状が次のものにも現れます
　place sister
　place brother
　place parent
　place child

引用：


症状がやっとクリアーになりました。
形状ファイルのエクスポートを例にとります。


１）legacy script

　Shade 9 までは OK

tell application "Shade 9"
seve shape in file filePath
end tell


　Shade 10 では不可

tell application "Shade 10"
seve shape in file filePath
end tell



２）クラス scene n を使用した場合

・Shade 9 まで
　file path の directory の記述は : でも / でも OK

・Shade 10
　file path の directory の記述は / のみ OK で、: は不可


　これは OK
tell application "Shade 10"
tell scene 1
save shape in "/Users/tkatoh/Documents/temp/00.shd"
end tell
end tell

　これはダメ
tell application "Shade 10"
tell scene 1
save shape in ":Users:tkatoh:Documents:temp:00.shd"
end tell
end tell


クラス scene n を使用した場合、

　save shape in filePath

であって、

　save shape in file filePath

ではないことに注意して下さい。



区切り文字に : が使用できないというのは Mac のルールからは大きな逸脱ですので、これはバグとして解消される可能性はありますね。

legacy script の不具合に対する扱いは全くもって不明です。
このままサポートされないという可能性は大いにあると思います。

引用：


でった☆さんから、インポート、エクスポートが正常に機能するケースについての指摘がありました。

ひょっとすると Apple Script の記述の仕方によって異なるのかもしれません。

本件についてはもっと検証を進めることにします。

（ その４）


３）機能は正常だが、result が返されない

以下で確認
　select sister
　select brother
　select parent
　select child

legacy script、クラス scene n を使用したスクリプト両方のケースで同じ症状になります。

tell application "Shade 10"
select sister 2
end tell

tell application "Shade 10"
tell scene 1
select sister 2
end tell
end tell



４）適用されているマスターサーフェスの handle No. を取得する
master surface が機能せず、指定するマスターサーフェスをオブジェクトに適用させる set master surface も機能しない。

tell application "Shade 10"
master surface
end tell

tell application "Shade 10"
set master surface to handleNo
end tell



５）インポート、エクスポート類が実行不可

形状データ、DXF、材質設定ファイルで確認していますが、他の種類のファイルでも同様と思われます。

tell application "Shade 10"
save DXF in file fileName
end tell

tell application "Shade 10"
load shape from file fileName
end tell


//////////////////////////////////////////////////////////


とりあえず、現時点で見つかったのは以上の通りです。


マイナーな legacy script のバグで、クラスを使用したスクリプトで代用できるものについては、省略しています。

中にはずっと以前から完全に誤った数値を返すにもかかわらず、バグフィックスされないまま放置されてしまっている legacy script もありますね。


script editor から Shade 10 の用語説明を開くと、解説文の日本語化がかなり進んでおり、Shade 9 に比べて、ずっと解りやすくなっています。



ちなみに拙作の Euclid Series は上記５）のバグが致命傷となって
動かすことが出来ません、全滅です。

次回のアップデータで改善されればいいのですが‥‥‥、ふむ、困ったものです。

（ その３）

２）クラス shape が変更された

例 - number of sons の場合（ パート内の子オブジェクトの下図をカウント ）


Shade 9 では：

tell application "Shade 9"
tell shape 1 of active objects of scene 1
number of sons
end tell
end tell

result ： 最初に選択されたオブジェクトの子オブジェクトの数
　　　　選択形状がパート以外であれば、エラーとなる


tell application "Shade 9"
tell shape of active objects of scene 1
number of sons
end tell
end tell

result ： 選択されたオブジェクトの子オブジェクトの数がリスト形式で返される
　　　　選択形状がパート以外であれば、missing value と表示される


Shade 10 では：

tell application "Shade 10"
tell active shape of scene 1
number of sons
end tell
end tell

result ： 選択されたオブジェクトの子オブジェクトの数がリスト形式で返される
　　　　選択形状がパート以外であれば、missing value と表示される

単体のパートオブジェクトの子オブジェクト数一つのみを得る方法は不明 （ 私の探し方が悪いだけかも ）


（ 続く ）

（ その2 ）

予め以下のことにご注意下さい。

a ）Shade 10 に関してのことであり、Shade 9 以前には当てはまりません。

b ）Shade 10.0.1 をベースにしていますが、仕様変更 なのか バグ なのかは不明なところもあり、場合によっては将来のアップデータで変更される（バグフィクスされる）可能性もあります。

c ）recording で記録されるのは legacy script のみで、クラスを使用したスクリプトは記録されません。



１）形状作成に関する legacy script が正常に機能しないが、クラス scene を使用すれば OK

以下で確認
　create disk
　create sphere
　create rotator joint
　start polygon / append point / finish polygon


これらは従来の legacy scipt では機能しません。
tell application "Shade 10"
create disk at {0,0,0} r 100 axis 1
end tell

クラス scene n を用いた python と同じ構文を持つ script で書けば OK です。
tell application "Shade 10"
tell scene 1
create disk at {0,0,0} r 100 axis 1
end tell
end tell


ここで、
a ）create disk, create sphere, create rotator joint に対しては native unit ( mm ) で数値を指定
b ）線形状を描く append point では current unit で数値を指定（ シーンの単位が cm で指定してあれば、cm で表した数値を用いる ）



また、クラスを用いた append point でのハンドル座標の指定は absolute のみで、relative はサポートされていません。

したがって、次のように書くとエラーとなります。
tell application "Shade 10"
tell scene 1
start polygon without closed
append point at {-200, 0, 200} in absolute {-300, 0, 300} out absolute {-150, 0, 150}
append point at {0, 0, 500} in absolute {-100, 0, 400} out absolute {100, 0, 600}
finish polygon
end tell
end tell

absolute を書かなければ OK です。
tell application "Shade 10"
tell scene 1
start polygon without closed
append point at {-200, 0, 200} in {-300, 0, 300} out {-150, 0, 150}
append point at {0, 0, 500} in {-100, 0, 400} out {100, 0, 600}
finish polygon
end tell
end tell


（ 続く ）

（ その１）

よほど古くからのユーザーでないと Apple script を使用していないとは思いますが、イーフロさんのサポート係も Apple script に関しては対応しきれないところもあるようです。

まあ、マイナーなスクリプトになってしまいましたから、このような状況もいたしかたないとも感じますが、Shade 10 になっていくつかの変更があるようなので、私が気づいた限りの注意点についておしらせいたします。


その前に、Shade 10 の apple script 変更の背景についてお話ししておきます。

イーフロさんのサポート係や最近の開発スタッフの中にはこれらの事情をご存じではない方も多いようで、混乱の元になっているようです。


＜ 過去からの経緯 ＞

python script がサポートされてから、apple script にも python と同じような構文を持つもの（クラスを使用する構文）が少しずつ準備されてきています。

Shade 10 において、これらのクラスが大幅に拡張されると同時に、一部が変更されたこともあって、Shade 9 までは完全にサポートされてきた従来の legacy script の一部が使用できなくなっています（仕様変更なのかバグなのかは不明）。


ここで、legacy script の仕様は次のようになっています。

・使用単位は native ( mm ) ではなくて current unit とする。（ python では native unit )
・序数は０基数（０から始まる数字 ）にする。（ pytoh と同じ ）


当初は次のルールで新しいクラスが作られることになっていました。

・使用単位は current unit とする。（ legacy script と同じ ）
・序数は Apple script のルールに合わせて１基数（１から始まる数字 ）にする。（ legacy script とは異なる ）


しかしながら、クラスに基づいた Apple script が拡張されるにつれ、なし崩し的に次のようなルールに変更されてしまいました。

・使用単位は native ( mm ) とする。（ python と同じ、legacy script とは異なる ）
・序数は０基数（０から始まる数字 ）にする。（ python と同じ、再び legacy script と同じに戻った ）


最終的には python とおなじルールに統一されたことになりますが、途中で変更されたため、一部のクラスでは古いルールをベースとして作られてしまっているものが混じっており、少々ややこしいことになっています。

（ 続く ）